%ffp
// works with tiles, 16 bit images and correct edge handling

Title      :"Gaussian Blur"
Filename   :"colorspace.8bf"
Description:"Gaussian Blur Example."
Copyright  :"© 2007  GPL"
Author     :"Alois Zingl"
Version    :"1.1  6 Mai 2008"
URL        :"http://free.pages.at/easyfilter/filtermeister.html"
Category   :"easyFilter"

ctl(0):"Blur (pixels)",divisor=10,range=(1,500)

OnFilterStart:
{
  double s = ctl(0)/(zoomFactor*7.4)+0.9; // Photoshop equivalent
  isTileable = !doingProxy;
  needPadding = fmin(256.0, s*sqrt(log(256.0)/log(2.0))); // radius
  bandWidth = 100+needPadding;
  
  // calc Gaussian bell shape
  s = -1.0/(s*s);
  for (i = 0; i < needPadding; i++)
    put((int)(32768.0*exp(i*i*s)), i);
  return false;
}

ForEveryTile:
{
  int Blur = needPadding-1;  // blur box radius
  int x, y, z;

  for (z = 0; z < planesWithoutAlpha; ++z) 
  {
    if (updateProgress((1-doingProxy)*y_start*planesWithoutAlpha*4+(y_end-y_start)*(4*z+1), 
                       (doingProxy?y_end-y_start:Y)*planesWithoutAlpha*4))
      abort();
    // vertical blur...
    for (x = max(0, x_start-Blur); x<min(X, x_end+Blur); ++x) 
    {    // loop +/- blur radius needed in case of preview zooming
      int Weight = 0, i;
      for (y = max(0, y_start-Blur); y <= min(Y-1, y_start+Blur); ++y) 
      {
        Weight += get(abs(y-y_start)); // sum up bell shape weight
        put(src(x, y, z), (y&511)+512); // for speed up buffer image pixels
      }
      for (y = y_start; y < y_end; ++y) 
      {
        double sum = 0;
        // can't use cnvY 'cause it does wrong for blur on the image edge
        for (i = max(0, y-Blur); i <= min(Y-1, y+Blur); ++i) 
          sum += get((i&511)+512)*get(abs(i-y)); // pixel * weight
        pset(x,y,z,(int)(sum/Weight));
        i = y+Blur+1;
        if (i<Y) 
          put(src(x, i, z), (i&511)+512); // buffer next image pixel
        else
          Weight -= get(Y-y-1); // if end edge reached sub shape weight
        if (y-Blur<0)
          Weight += get(y+1); // if still on edge sum up next shape weight
      }
    }
    if (updateProgress((1-doingProxy)*y_start*planesWithoutAlpha*4+(y_end-y_start)*(4*z+3), 
                       (doingProxy?y_end-y_start:Y)*planesWithoutAlpha*4))
      abort();

    // horizontal blur...
    for (y = y_start; y < y_end; ++y) 
    {
      int Weight = 0, i;
      for (x = max(0, x_start-Blur); x <= min(X-1, x_start+Blur); ++x) 
      {
        Weight += get(abs(x-x_start)); // sum up bell shape weight
        put(pget(x, y, z),(x&511)+512); // for speed up buffer image pixels
      }
      for (x = x_start; x < x_end; ++x) 
      {
        double sum = 0;
        // can't use cnvY 'cause it does wrong for blur on the image edge
        for (i = max(0, x-Blur); i <= min(X-1, x+Blur); ++i) 
          sum += get((i&511)+512)*get(abs(i-x)); // pixel * weight
        pset(x, y, z, (int)(sum/Weight));
        i = x+Blur+1;
        if (i<X) 
          put(pget(i, y, z),(i&511)+512); // buffer next image pixel
        else
          Weight -= get(X-x-1); // if end edge reached sub shape weight
        if (x-Blur<0)
          Weight += get(x+1); // if still on edge sum up next shape weight
      }
    }
  }
  return true;  //Done!
}

OnFilterEnd:
{
  updateProgress(0, 1);
  return false;
}