%ffp
Category: "easy.Filter"
Title:    "Blur - Sharpen"
Version:  "1.0"
Filename: "blursharpen.8bf"
Author:   "Alois Zingl"
Copyright:"© 2008"
URL:      "http://free.pages.at/easyfilter/gauss.html"
Description:"Improve contrast by blur and sharpen."

ctl(0): "Radius (pixels)", val = 4, divisor = 2, range=(0,340)
ctl(1): "Blur (%)", range = (0, 100), val = 32
ctl(2): "Sharpen (%)", val = 64
ctl(3): "Threshold (0..255)", val = 16

OnFilterStart:
{
  int Blur = doingProxy?(ctl(0)+scaleFactor/2)/scaleFactor:ctl(0); // blur radius
  needPadding = 3*Blur/2+2;
  isTileable = !doingProxy; // split large images
  bandWidth = 100+4*needPadding;
  return false;
}

ForEveryTile:
{
  int Blur = sqrt(1.0+ctl(0)*ctl(0)/(scaleFactor*scaleFactor));  // blur radius
  int x, y, z, i, Blur2 = (3*Blur+1)/2;
  double Weight = Blur*Blur*Blur;
  int th = (imageMode<GRAY16MODE?1:128)*ctl(3);  // threshold

  for (z=0; z < Z; ++z) // for all color planes
  {
    if (updateProgress(y_start+(y_end-y_start)*z/Z, Y)) abort();

    for (x = x_start; x<x_end; ++x)     // vertical blur for every row
    {
      double dif = 0., der = 0., sum = 0.;
      for (y = y_start-3*Blur; y < y_start; ++y)  // initialize row
      {
        sum += der; der += dif;    // accumulate pixel blur
        p = src(x, y+Blur2, z); // pixel value
        put(p, y+3*Blur);        // buffer pixel, min buffer size: 3*Blur
        dif += p;           // accumulate differences {+1,
        if (y+2*Blur >= y_start) dif -= 3*get(y+2*Blur);// -3,
        if (y+Blur >= y_start) dif += 3*get(y+Blur);    //     +3, (-1)}
      }
      for (; y<y_end; ++y)
      {                                // inner vertical blur loop
        sum += der; der += dif;    // accumulate pixel blur
        pset(x, y, z, (int)(sum/Weight)); // set blurred pixel
        p = src(x, y+Blur2, z); // next pixel
        put(p, y+3*Blur);        // buffer pixel
        dif += p+3*(get(y+Blur)-get(y+2*Blur))-get(y);  // {+1,-3,+3,-1}
      } // y
    } // x

    for (y = y_start; y < y_end; ++y)     // horizontal blur for every column
    {
      double dif = 0., der = 0., sum = 0.;
      for (x = x_start-3*Blur; x < x_start; ++x)  // initialize column
      {
        sum += der; der += dif;    // accumulate pixel blur
        p = pget(x+Blur2, y, z); // pixel value
        put(p, x+3*Blur);        // buffer pixel, min buffer size: 3*Blur
        dif += p;            // accumulate differences {+1,
        if (x+2*Blur >= x_start) dif -= 3*get(x+2*Blur); // -3,
        if (x+Blur >= x_start) dif += 3*get(x+Blur);     //     +3, (-1)}
      }
      for (; x < x_end; ++x)
      {                                // inner horizontal blur loop
        sum += der; der += dif;    // accumulate pixel blur
        p = (int)(sum/Weight)-src(x, y, z);  // local contrast
        p = (2*ctl(1)*p - ctl(2)*(abs(p-th)-abs(p+th)+2*p))/200; // blur - sharpen
        pset(x, y, z, src(x, y, z)+p);
        p = pget(x+Blur2, y, z); // next pixel
        put(p, x+3*Blur);         // buffer pixel
        dif += p+3*(get(x+Blur)-get(x+2*Blur))-get(x);  // {+1,-3,+3,-1}
      } // x
    } // y
  } // color plane
  return true;  //Done!
}

OnFilterEnd:
{
  updateProgress(0, 1);
  return false;
}